CFFTP: OPENING AND CLOSING FTP SERVER CONNECTIONS |
Description To establish a connection with an FTP server, you use the open action with a connection attribute.
Syntax
    <cfftp
       action = "action"
       username = "name"
       password = "password"
       server = "server"
       timeout = "timeout in seconds"
       port = "port"
       connection = "name"
       proxyServer = "proxy server"
       retryCount = "number"
       stopOnError = "yes" or "no"
       passive = "yes" or "no">
See also cfhttp, cfldap, cfmail, cfpop
Usage When you establish a connection with cfftp action="open" and specify a name in the connection attribute, ColdFusion caches the connection so that you can reuse it to perform additional FTP operations. When you use a cached connection for subsequent FTP operations, you do not have to specify the username, password, or server connection attributes. The FTP operations that use the same connection name automatically use the information stored in the cached connection. Using a cached connection helps save connection time and improves file transfer performance.

You do not need to open a connection for single, simple, FTP operations, such as GetFile or PutFile.

To keep a connection open throughout a session or longer, put the connection name in the Session or Application scope; for example, specify connection="Session.FTPConnection". However, if you do this, you must specify the full variable name in all FTP operations, and you must use the close action when you are finished. Keeping a connection open prevents others from using the FTP server; so close a connection as soon as possible. If you do not assign the connection name to Session or Application variable, the connection remains open for the current page only, and you do not have to close it manually.

Changes to a cached connection, such as changing retryCount or timeout values, might require reestablishing the connection.

Example
    <p>cfftp lets users implement File Transfer Protocol operations.
    By default, cfftp caches an open connection to an FTP server.
    <p>cfftp operations are usually of two types:
    <ul>
       <li>Establishing a connection
       <li>Performing file and directory operations
    </ul>
    <p>This example opens and verifies a connection, lists the files in a
    directory, and closes the connection.
    <p>Open a connection
    <cfftp action = "open"
       username = "anonymous"
       connection = "My_query"
       password = "youremail@email.com"
       server = "ftp.tucows.com"
       stopOnError = "Yes">
    <p>Did it succeed? <cfoutput>#cfftp.succeeded#</cfoutput>
    <p>List the files in a directory:
    <cfftp action = "LISTDIR"
        stopOnError = "Yes"
        name = "ListFiles"
        directory = "/"
        connection = "my_query">
    <cfoutput query = "ListFiles">
       #name#<br>
    </cfoutput>

    <p>Close the connection:
    <cfftp action = "close"
    connection = "My_query"
    stopOnError = "Yes">
    <p>Did it succeed? <cfoutput>#cfftp.succeeded#</cfoutput>

ACTION |
| Required
FTP operation to perform.

- open: creates an FTP connection
- close: terminates an FTP connection

USERNAME |
| Required if action = "open"
User name to pass in the FTP operation.

PASSWORD |
| Required if action = "open"
Password to log in the user.

SERVER |
| Required if action = "open"
FTP server to which to connect; for example, ftp.myserver.com

TIMEOUT |
| Optional
Default value: "30" Value in seconds for the timeout of all operations, including individual data request operations.

PORT |
| Optional
Default value: "21" Remote port to which to connect.

CONNECTION |
| Optional, but always used with open or close
Name of the FTP connection. If you specify the username, password, and server attributes, and if no connection exists for them, ColdFusion creates one. Calls to cfftp with the same connection name reuse the connection.

PROXYSERVER |
| Optional
String. Name of proxy server (or servers) to use, if proxy access is specified.

RETRYCOUNT |
| Optional
Default value: "1 " Number of retries until failure is reported.

STOPONERROR |
| Optional
Default value: "no"

- yes: halts processing, displays an appropriate error.
- no: populates these variables:

- cfftp.succeeded - yes or no.
- cfftp.errorCode - Error number. See the IETF Network Working Group RFC 959: File Transfer Protocol (FTP) www.ietf.org/rfc/rfc0959.txt.
- cfftp.errorText - Message text.

For conditional operations, use cfftp.errorCode. Do not use cfftp.errorText for this purpose.

PASSIVE |
| Optional
Default value: "no"

- yes: enables passive mode.
- no