This reference is for Processing 2.0+. If you have a previous version, use the reference included with your software. If you see any errors or have suggestions, please let us know. If you prefer a more technical reference, visit the Processing Javadoc.

Name | ### bufferUntil()
Examples |
    // Example by Tom Igoe

    import processing.serial.*;

    Serial myPort;    // The serial port
    PFont myFont;     // The display font
    String inString;  // Input string from serial port
    int lf = 10;      // ASCII linefeed

    void setup() {
      size(400,200);
      // Make your own font. It's fun!
      myFont = loadFont("ArialMS-18.vlw");
      textFont(myFont, 18);
      // List all the available serial ports:
      println(Serial.list());
      // Open the port you are using at the rate you want:
      myPort = new Serial(this, Serial.list()[0], 9600);
      myPort.bufferUntil(lf);
    }

    void draw() {
      background(0);
      text("received: " + inString, 10,50);
    }

    void serialEvent(Serial p) {
      inString = p.readString();
    }
Description | Sets a specific byte to buffer until before calling serialEvent().

Updated on May 19, 2014 05:30:04pm PDT