This reference is for Processing 2.0+. If you have a previous version, use the reference included with your software. If you see any errors or have suggestions, please let us know. If you prefer a more technical reference, visit the Processing Javadoc.

Class | JSONObject
Name | ### getJSONArray()
Examples |
    // The following short JSON file called "data.json" is parsed
    // in the code below. It must be in the project's "data" folder.
    //
    // { "animals": [
    //   {
    //     "id": 0,
    //     "species": "Capra hircus",
    //     "name": "Goat"
    //   },
    //   {
    //     "id": 1,
    //     "species": "Panthera pardus",
    //     "name": "Leopard"
    //   },
    //   {
    //     "id": 2,
    //     "species": "Equus zebra",
    //     "name": "Zebra"
    //   } ]
    // }

    JSONObject json;

    void setup() {

      json = loadJSONObject("data.json");

      JSONArray values = json.getJSONArray("animals");

      for (int i = 0; i < values.size(); i++) {

        JSONObject animal = values.getJSONObject(i);

        int id = animal.getInt("id");
        String species = animal.getString("species");
        String name = animal.getString("name");

        println(id + ", " + species + ", " + name);
      }
    }

    // Sketch prints:
    // 0, Capra hircus, Goat
    // 1, Panthera pardus, Leopard
    // 2, Equus zebra, Zebra
Description | Retrieves the JSONArray with the associated key.
Syntax |
    .getJSONArray(key)
Parameters |
key | String: a key string
Returns | JSONArray
Related | getJSONObject() setJSONObject() setJSONArray()

Updated on May 19, 2014 05:30:04pm PDT