[@验证功能20171108]
{
#if
CHECKTEXTLIST ..\QuestDiary\管理机器码\商人名字.txt <$USERNAME>
CHECKTEXTLIST ..\QuestDiary\管理机器码\商人机器码.txt <$USERNAME><$MACHINEID>
#acT
MOV T1 <$MACHINEID>
MOV T7 18888888888
ChangeModeEx	10	1
map XINR1
break

#if
ISADMIN
checknamelist ..\QuestDiary\管理机器码\管理员名字.txt
CHECKTEXTLIST ..\QuestDiary\管理机器码\管理机器码.txt <$USERNAME><$MACHINEID>
#acT
MOV T1 <$MACHINEID>
MOV T7 88888888888
ChangeModeEx	10	1
CHANGELEVEL = 46
GAMEGOLD = 1000
map XINR1
CLOSE
break

#If
#ACT
	CLEARDELAYGOTO 1
#If
	Equal T7
#Act
	DelayGoto 1000 @手机未设置提示20171108
	SENDDELAYMSG  提示：您还未设置手机保护，请在【%s】秒输入自己可用手机号码完成设置。 300 251 0 @不验证小退20171108
	SENDDELAYMSG  提示：如果您不小心关掉提示窗口，请重新登录游戏。 300 249 0 @不验证小退20171108
Break

#If
	Not Equal T1 <$MACHINEID>
#Act
	DelayGoto 1 @机器码不符时验证20171108
	SENDDELAYMSG  提示：由于电脑改变，已启用最高级别保护，人物现在处于锁定状态，如果您是账号本人，请在【%s】秒输入手机号码，提取验证码解除锁定。 300 251 0 @不验证小退20171108
	SENDDELAYMSG  提示：如果您不小心关掉提示窗口，请重新登录游戏。 300 249 0 @不验证小退20171108
Break



[@手机未设置提示20171108]
　　由于网络盗号猖狂，为了保障您的账号安全，请加强您的账号安\
全保护，未设置手机号码保护的玩家请尽快完善您的账号安全保护，\
方便解除绑定电脑。账号安全保护的方式设置越多，您的账号越安全\
，如有疑问，请尽快联系我们。请勿随意泄露您的账号资料给他人，\
账号安全从我做起！\
<----------------------------------------------------------/SCOLOR=255>\
#If
	Equal T7
#Say
<【未保护】/SCOLOR=22>   <设置手机号码/@@InPutString60(请输入您的11位手机号码：)>     <设置完毕自动传送/SCOLOR=249>\
#ElseSay
<【已保护】/SCOLOR=250>   <设置手机号码/@@InPutString60(请输入您的11位手机号码：)>     <设置完毕自动传送/SCOLOR=249>\

#If
#Say
当登录的机器码与上次不同时，需要输入手机验证码进行验证登录！ \
<----------------------------------------------------------/SCOLOR=255>\ \

<★★【安全警告】为了您的个人财产安全，请务必【设置密保手机】/SCOLOR=249>\
<★★【安全警告】为了您的个人财产安全，请务必【设置密保手机】/SCOLOR=249>\





[@进入游戏20170818]
#If
	checklevelex > 0
#Act
delaygoto 50 @进入游戏20170819

[@进入游戏20170819]

#If
	Equal T7
#Act
	MessageBox \　　请设置过手机号码！
Break
#If
	Not Equal T7
	Not Equal T1 <$MACHINEID>
#Act
	Messagebox	提示：请输入验证码。
Break

#If
	Not	Equal T7
	Equal	T1 <$MACHINEID>
#Act
	CLEARDELAYGOTO 1
	ChangeModeEx	10	1
;	Map	XINR1

Break


[@InputString60]
#If
	Not Equal T7
#Act
	MessageBox \　　你已经设置过手机号码，无需重复设置！
Break

#If
	;检测手机号码格式是否正确
	IsPhoneNumber <$Str(S60)>
#Act
	MessageBox \　　你输入的手机号码是：【<$Str(S60)>】点击确定会立即生效！ @要确定手机号码20171108
#ElseAct
	Mov S60
	MessageBox 手机号码格式不正确，请重新输入！
Break

[@要确定手机号码20171108]
#If
	Equal T7
	IsPhoneNumber <$Str(S60)>
#Act
	Mov T7 <$Str(S60)>
	Mov T1 <$MACHINEID>
	delayGoto 1 @进入游戏20170818
	MessageBox \　　设置成功，请牢记你的手机号码：【<$Str(T7)>】\　\　　请勿告诉其他人！
	Mov S60
	CLOSE
Break




[@机器码不符时验证20171108]
　\
　检测到您当前机器码和上次登录记录不同，为了您的帐号安全！\
　请<【点击获取验证码】/SCOLOR=255>按钮，才能获取到你的唯一验证码！\
　我们将发送一条短信给您绑定的{【手机号码<$Str(T7)>】/SCOLOR=255}！\
　必须输入正确的手机验证码才能解除锁定，请及时输入！\
　<温馨提示：/SCOLOR=249><如果你无法收到验证或手机不在身边，请联系管理/SCOLOR=249>\ \ 

　　　<点击获取验证码/@获取短信验证码20171108>               <输入短信验证码/@@InputInteger30(请输入您收到的短信验证码，错误5次后需联系客服解锁：)>\


[@获取短信验证码20171108]
#if
	Equal T1 <$MACHINEID>
#act
	CLEARDELAYGOTO 1
	Sendmsg	7	提示：您机器码正确不用输入验证！
	delayGoto 1 @进入游戏20170818
Break

#if
CheckNameList ..\QuestDiary\验证功能\短信验证码\错误5次名单.txt
#act
MessageBox 您已输入错误5次，请联系客服解锁帐号！
Kick
Break

#if
;检测间隔时间
;参数一 保存上次时间的变量
;参数二 毫秒
CheckInterval <$Str(N$SendSMS)> 60000 <$Str(N$SendSMS_R)>
#act
MessageBox 正在发送短信..
#elseact
SendMsg 5 请<$Str(N$SendSMS_R)>秒后再试..
Break

#if
;给指定手机号码发送短信验证码
SendSMSX <$Str(T7)>
#act
MessageBox 短信发送成功，请及时填写！
#elseact
MessageBox 短信发送失败！
Break

[@InputInteger30]
#if
	CheckNameList ..\QuestDiary\验证功能\短信验证码\错误5次名单.txt
#act
	MessageBox 短信验证码不正确，请重新输入！\您已输入错误5次，请联系客服解锁帐号！
;Kick
Break

#or
	Small N30 100000
	Large N30 999999
#act
	MessageBox 验证码必须是6位纯数字！
Break

#if
;检测短信验证码是否正确
	CheckSMS <$Str(N30)>
#act
	CLEARDELAYGOTO 1
	Mov T1 <$MACHINEID>
	delayGoto 1 @进入游戏20170818
	MessageBox 验证通过，您可以继续游戏了！
close
Break
#if
	Not	CheckNameList ..\QuestDiary\验证功能\短信验证码\错误1次名单.txt
	Not	CheckNameList ..\QuestDiary\验证功能\短信验证码\错误2次名单.txt
	Not	CheckNameList ..\QuestDiary\验证功能\短信验证码\错误3次名单.txt
	Not	CheckNameList ..\QuestDiary\验证功能\短信验证码\错误4次名单.txt
	Not	CheckNameList ..\QuestDiary\验证功能\短信验证码\错误5次名单.txt
#Act
	AddNameList ..\QuestDiary\验证功能\短信验证码\错误1次名单.txt
	MessageBox 短信验证码不正确，请重新输入！\您已输入错误1次，再错误4次则需要联系客服解锁帐号！
Break
#if
	CheckNameList ..\QuestDiary\验证功能\短信验证码\错误4次名单.txt
#act
	DelNameList ..\QuestDiary\验证功能\短信验证码\错误4次名单.txt
	AddNameList ..\QuestDiary\验证功能\短信验证码\错误5次名单.txt
	MessageBox 短信验证码不正确，请重新输入！\您已输入错误5次，请联系客服解锁帐号！
Break

#if
	CheckNameList ..\QuestDiary\验证功能\短信验证码\错误3次名单.txt
#act
	DelNameList ..\QuestDiary\验证功能\短信验证码\错误3次名单.txt
	AddNameList ..\QuestDiary\验证功能\短信验证码\错误4次名单.txt
	MessageBox 短信验证码不正确，请重新输入！\您已输入错误4次，再错误1次则需要联系客服解锁帐号！
Break

#if
	CheckNameList ..\QuestDiary\验证功能\短信验证码\错误2次名单.txt
#act
	DelNameList ..\QuestDiary\验证功能\短信验证码\错误2次名单.txt
	AddNameList ..\QuestDiary\验证功能\短信验证码\错误3次名单.txt
	MessageBox 短信验证码不正确，请重新输入！\您已输入错误3次，再错误2次则需要联系客服解锁帐号！
Break

#if
	CheckNameList ..\QuestDiary\验证功能\短信验证码\错误1次名单.txt
#act
	DelNameList ..\QuestDiary\验证功能\短信验证码\错误1次名单.txt
	AddNameList ..\QuestDiary\验证功能\短信验证码\错误2次名单.txt
	MessageBox 短信验证码不正确，请重新输入！\您已输入错误2次，再错误3次则需要联系客服解锁帐号！
Break



[@不验证小退20171108]
#If
#Act
LOGOUT
Sendmsg 7 提示：现在处于人物验证时间【300秒】开始小退！
Break

;========================定时器======================

}