用纯ASP代码实现图片上传并存入数据库中

---摘自《eNet学院》
用ＡＳＰ编写网站应用程序时间长了，难免会遇到各式各样的问题，其中关于如何上传文件到服务器恐怕是遇见最多的问题了，尤其是上传图片，比如你想要在自己的社区里面实现类似网易虚拟社区提供的“每日一星”的功能，就要提供给网友上传照片的功能。上传图片文件到服务器可以使用各种免费的文件上传组件，使用起来功能虽然很强大，但是由于很多情况下，我们只能使用免费的支持ＡＳＰ的空间或者租用别人的虚拟空间，对于第一种情况，我们根本就没有可能来使用文件上传组件；至于第二种情况，我们也要付出不少的“银子”才可以。除非你拥有自己的虚拟主机，你就可以随便的在服务器上面安装自己所需要的组件，这种情况对于大多数人来说是可望而不可及的。那我们就没有办法了吗？呵呵，答案是肯定的（当然是肯定的了，要不然我也没法写出这篇文章啊）。下面就让我们一起来使用纯ＡＳＰ代码来实现图片的上传以及保存到数据库的功能（顺便也实现显示数据库中的图片到网页上的功能）。
首先我们先来熟悉一下将要使用的对象方法。我们用来获取上一个页面传递过来的数据一般是使用Request对象。同样的，我们也可以使用Request对象来获取上传上来的文件数据，使用的方法是Request.BinaryRead()。而我们要从数据库中读出来图片的数据显示到网页上面要用到的方法是：
Request.BinaryWrite()。在我们得到了图片的数据，要保存到数据库中的时候，不可以直接使用Insert语句对数据库进行操作，而是要使用ADO的AppendChunk方法，同样的，读出数据库中的图片数据，要使用GetChunk方法。各个方法的具体语法如下：
* Request.BinaryRead语法：
variant = Request.BinaryRead(count)
参数
variant
返回值保存着从客户端读取到数据。
count
指明要从客户端读取的数据量大小，这个值小于或者等于使用方法
Request.TotalBytes得到的数据量。
* Request.BinaryWrite语法：
Request.BinaryWrite data
参数
data
要写入到客户端浏览器中的数据包。
* Request.TotalBytes语法：
variant = Request.TotalBytes
参数
variant
返回从客户端读取到数据量的字节数。
* AppendChunk语法
将数据追加到大型文本、二进制数据 Field 或 Parameter 对象。
object.AppendChunk Data
参数
object Field 或 Parameter 对象
Data 变体型，包含追加到对象中的数据。
说明
使用 Field 或 Parameter 对象的 AppendChunk 方法可将长二进制或字符数据填写到对象中。在系统内存有限的情况下，可以使用 AppendChunk 方法对长整型值进行部分而非全部的操作。
* GetChunk语法
返回大型文本或二进制数据 Field 对象的全部或部分内容 。
variable = field.GetChunk( Size )
返回值
返回变体型。
参数
Size 长整型表达式，等于所要检索的字节或字符数。
说明
使用 Field 对象的 GetChunk 方法检索其部分或全部长二进制或字符数据。在系统内存有限的情况下，可使用 GetChunk 方法处理部分而非全部的长整型值。
GetChunk 调用返回的数据将赋给“变量”。如果 Size 大于剩余的数据，则
GetChunk 仅返回剩余的数据而无需用空白填充“变量”。如果字段为空，则
GetChunk 方法返回 Null。
每个后续的 GetChunk 调用将检索从前一次 GetChunk 调用停止处开始的数据。但是，如果从一个字段检索数据然后在当前记录中设置或读取另一个字段的值，ADO 将认为已从第一个字段中检索出数据。如果在第一个字段上再次调用 GetChunk 方法，ADO 将把调用解释为新的 GetChunk 操作并从记录的起始处开始读取。如果其他 Recordset 对象不是首个 Recordset 对象的副本，则访问其中的字段不会破坏 GetChunk 操作。如果 Field 对象的 Attributes 属性中的 adFldLong 位设置为 True，则可以对该字段使用 GetChunk 方法。如果在 Field 对象上使用 Getchunk 方法时没有当前记录，将产生错误 3021（无当前记录）。接下来，我们就要来设计我们的数据库了，作为测试我们的数据库结构如下（Ａｃｃｅｓｓ９７）：
字段名称　　　　类型　　　　描述
id 　　　自动编号　　　主键值
img OLE对象　　　用来保存图片数据
对于在MS SQL Server7中，对应的结构如下：
字段名称　　　　类型　　　　描述
id 　　　　int(Identity)　主键值
img 　　image　　　 　用来保存图片数据
现在开始正式编写我们的纯ＡＳＰ代码上传部分了，首先，我们有一个提供给用户的上传界面，可以让用户选择要上传的图片。代码如下
（upload.htm）：
<html>
<body>
<center>
<form name="mainForm" enctype="multipart/form-data"
action="process.asp" method=post>
<input type=file name=mefile><br>
<input type=submit name=ok value="OK">
</form>
</center>
</body>
</html>
注意代码中黑色斜体的部分，一定要在Form中有这个属性，否则，将无法得到上传上来的数据。
接下来，我们要在process.asp中对从浏览器中获取的数据进行必要的处理，因为我们在process.asp中获取到的数据不仅仅包含了我们想要的上传上来的图片的数据，也包含了其他的无用的信息，我们需要剔除冗余数据，并将处理过的图片数据保存到数据库中，这里我们以Ａｃｃｅｓｓ９７为例。具体代码如下（process.asp）：
<%
response.buffer=true
formsize=request.totalbytes
formdata=request.binaryread(formsize)
bncrlf=chrB(13) & chrB(10)
divider=leftB(formdata,clng(instrb(formdata,bncrlf))-1)
datastart=instrb(formdata,bncrlf & bncrlf)+4
dataend=instrb(datastart+1,formdata,divider)-datastart
mydata=midb(formdata,datastart,dataend)
set connGraph=server.CreateObject("ADODB.connection")
connGraph.ConnectionString="driver={Microsoft Access Driver (*.mdb)};DBQ=" &
server.MapPath("images.mdb") & ";uid=;PWD=;"
connGraph.Open
set rec=server.createobject("ADODB.recordset")
rec.Open "SELECT * FROM [images] where id is null",connGraph,1,3
rec.addnew
rec("img").appendchunk mydata
rec.update
rec.close
set rec=nothing
set connGraph=nothing
%>
好了，这下我们就把上传来的图片保存到了名为images.mdb的数据库中了，剩下的工作就是要将数据库中的图片数据显示到网页上面了。一般在ＨＴＭＬ中，显示图片都是使用<IMG>标签，也就是<IMG SRC="图片路径">，但是我们的图片是保存到了数据库中，“图片路径”是什么呢？呵呵，其实这个SRC属性除了指定路径外，也可以这样使用哦：
<IMG SRC="showimg.asp?id=xxx">
所以，我们所要做的就是在showimg.asp中从数据库中读出来符合条件的数据，并返回到SRC属性中就可以了，具体代码如下（showimg.asp）：
<%
set connGraph=server.CreateObject("ADODB.connection")
connGraph.ConnectionString="driver={Microsoft Access Driver (*.mdb)};DBQ=" &
server.MapPath("images.mdb") & ";uid=;PWD=;"
connGraph.Open
set rec=server.createobject("ADODB.recordset")
strsql="select img from images where id=" & trim(request("id"))
rec.open strsql,connGraph,1,1
Response.ContentType = "image/*"
Response.BinaryWrite rec("img").getChunk(7500000)
rec.close
set rec=nothing
set connGraph=nothing
%>
注意在输出到浏览器之前一定要指定Response.ContentType = "image/*"，以便正常显示图片。
最后要注意的地方是，我的process.asp中作的处理没有考虑到第一页(upload.htm)中还有其他数据，比如<INPUT type=tesxt name=userid>等等，如果有这些项目，你的process.asp就要注意处理掉不必要的数据。怎么样，其实上传图片并保存到数据库很简单吧，这样再也不用为自己的空间无法使用各类的上传组件发愁了吧。还等什么？赶快试一试吧。
（以上所有程序均在WinNT4.0英文版，IIS4，Access97/MS SQL Server7.0中运行通过）