<?xml version="1.0" encoding="ISO-8859-1" ?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                version="1.0">

<xsl:import href="Default_seeElement.xsl" />

<xsl:output method="xml" version="1.0" encoding="ISO-8859-1" indent="yes"/>


<!--
///////////////////////////////////////////////////////////////
Generate PHPEdit compatible table of content.

Copyright 2003 DiGi <DiGi@QR.cz> http://www.qr.cz/

 note: you must edit generated file - remove encoding="UTF-16" from first line
       - this looks like bug in msxml parser
       
 Generate your help pages to same folder and restart PHPedit...      

///////////////////////////////////////////////////////////////
-->



<!--
///////////////////////////////////////////////////////////////////////
// match="/"
///////////////////////////////////////////////////////////////////////
-->
<xsl:template match="/">
  <xsl:element name="Help">
    <xsl:element name="Caption">
      <xsl:value-of select="/ParsedDocumentation/@title" />
    </xsl:element>
    <xsl:element name="Link">
      <xsl:text>index.html</xsl:text>
    </xsl:element>
    <xsl:apply-templates select="/ParsedDocumentation/Directory"><xsl:sort select="@name" /></xsl:apply-templates>
    <xsl:apply-templates select="/ParsedDocumentation/File"><xsl:sort select="@name" /></xsl:apply-templates>
  </xsl:element>
</xsl:template>

<!--
///////////////////////////////////////////////////////////////////////
// File
///////////////////////////////////////////////////////////////////////
-->
<xsl:template match="File">
<Node>
  <Caption><xsl:value-of select="@name" /></Caption>
  <Link><xsl:call-template name="uri.file">
        <xsl:with-param name="File" select="." />
      </xsl:call-template>
  </Link>
    <!-- CLASS -->
    <xsl:for-each select="Class">
    <Node>
	  <Caption><xsl:value-of select="Name" /></Caption>
	  <Link><xsl:call-template name="uri.class">
        <xsl:with-param name="ClassName"><xsl:value-of select="Name" /></xsl:with-param>
        </xsl:call-template>
      </Link>
    </Node>
    </xsl:for-each>  
    <!-- FUNCTION -->
    <xsl:for-each select="Function">
    <Node>
	  <Caption><xsl:value-of select="Name" /></Caption>
	  <Link>
	  	<xsl:call-template name="uri.function.byNode"><xsl:with-param name="FunctionNode" select="." /></xsl:call-template>
      </Link>
    </Node>
    </xsl:for-each>  
</Node>	
</xsl:template>

<!--
///////////////////////////////////////////////////////////////////////
// Directory
///////////////////////////////////////////////////////////////////////
-->
<xsl:template match="Directory">
  <!-- don't include empty directories -->
  <xsl:if test="count(.//File) > 0">
    <Node>
      <Caption><xsl:value-of select="@name" /></Caption>
      <Link/>
      <xsl:apply-templates select="Directory"><xsl:sort select="@name" /></xsl:apply-templates>
      <xsl:apply-templates select="File"><xsl:sort select="@name" /></xsl:apply-templates>
    </Node>
  </xsl:if>
</xsl:template>

</xsl:stylesheet>
