' CreateLink.vbs
'========================   Описание   =====================================
' Создание ярлыка папки/файла открытого на редактирование
'========================  Параметры =======================================
' 1-й параметр: Путь\где\создавать\ярлык (по умолчанию Рабочий стол) (можно использовать относительные пути)
' 2-й параметр:
'    0 - для файла
'    1 - для папки
' любой 3-й параметр создаст ярлык для AkelPad.exe
'========================    Примеры    ====================================
'  "&Ярлыки..." Icon("a%\AkelFiles\Plugs\Link.dll",2)
'   {
' -"Создать ярлык файла на Рабочем столе" Call("Scripts::Main", 1, "CreateLink.vbs", `"" "0"`) Icon("a%\AkelFiles\Plugs\Link.dll",1)
' -"Создать ярлык файла в панели ''Быстрого запуска''" Call("Scripts::Main", 1, "CreateLink.vbs", `"%%APPDATA%%\Microsoft\Internet Explorer\Quick Launch" "0"`) Icon("a%\AkelFiles\Plugs\Link.dll",3)
'   SEPARATOR
' -"Создать ярлык папки на Рабочем столе" Call("Scripts::Main", 1, "CreateLink.vbs", `"" "1"`) Icon("a%\AkelFiles\Plugs\Link.dll",529)
' -"Создать ярлык папки в панели ''Быстрого запуска''" Call("Scripts::Main", 1, "CreateLink.vbs", `"%%APPDATA%%\Microsoft\Internet Explorer\Quick Launch" "1"`) Icon("a%\AkelFiles\Plugs\Link.dll",0)
' -"Создать ярлык папки в панели ''Отправить в...''" Call("Scripts::Main", 1, "CreateLink.vbs", `"%%APPDATA%%\Microsoft\Windows\SendTo" "1"`) Icon("a%\AkelFiles\Plugs\Link.dll",0)
' -"Создать ярлык папки в панели ''Ссылки на папки''" Call("Scripts::Main", 1, "CreateLink.vbs", `"%%USERPROFILE%%\Links" "1"`) Icon("a%\AkelFiles\Plugs\Link.dll",0)
'   }

' используется Functions.vbs, который следует положить в ...AkelFiles\Plugs\Scripts\Include\

' Автор:           Аверин Андрей
' Версия:          1.1 (18.07.2011 - 12.08.2012)
' Mail:            Averin-And@yandex.ru
' Site:            http://tc-image.3dn.ru/forum/9-345-1067-16-1333460103
' Site:            http://akelpad.sourceforge.net/forum/viewtopic.php?p=13649#13649
'===========================================================================
File = AkelPad.GetEditFile(0)
With WScript
  Cnt = .Arguments.Count
  If Cnt > 0 Then
    Path = .Arguments(0)
    If Cnt > 1 Then
      Param = .Arguments(1) : If Cnt > 2 Then File = AkelPad.GetAkelDir(0) & "\AkelPad.exe"
    End If
  End If
End With

If Len(File) = 0 Then WScript.Quit
Call AkelPad.Include("Functions.vbs")
Set WSH = CreateObject("WScript.Shell")

If Len(Path) = 0 Then
  Path = WSH.SpecialFolders("Desktop")
Else
  If InStr(Path, "%") > 0 Then Path = GetPath(Path)
End If
If Len(Param) = 0 Then Param = 0

With CreateObject("Scripting.FileSystemObject")
  If Param = 1 Then File = .GetParentFolderName(File)
  Name = .GetBaseName(File)
  Dir = .GetParentFolderName(File)
End With

With WSH.CreateShortcut( Path & "\" & Name & ".lnk")
  .Arguments = ""
  .Description = ""
  .IconLocation = ",0"
  .TargetPath = File
  .WindowStyle = 1
  .WorkingDirectory = Dir
  .Save
End With

Set WSH = Nothing : WScript.Quit